Consultations

Consultations#

A consultation is the process of asking for feedback on a draft of a legislative resource.

Example#

Throughout this sub-page, the following consultation with a possible impact on the federal constitution is used as an example:

URI#

The URI of a consultation contains the following parts:

  • Standard namespace and path: https://fedlex.data.admin.ch/eli/

  • the part dl/proj is used as path for all consultations

  • YYYY/ is the year of the consultation

  • ID an identifier that has no specific meaning but restarts every year

  • cons_1 is used for every consultation

General Structure#

Every consultation is of type jolux:Consultation.

jolux:Consultation

The owl:Class jolux:Consultation is used for consultations.

A jolux:Consultation has a foreseen impact to a legislative resource. This is given by jolux:foreseenImpactToLegalResource:

jolux:foreseenImpactToLegalResource

The object property jolux:foreseenImpactToLegalResource is used to connect a jolux:Consultation to a jolux:Work (usually a jolux:ConsolidationAbstract).

The jolux:Consultation is structured into different jolux:ConsultationTask that are connected to the jolux:Consultation with the object property jolux:hasSubTask:

jolux:ConsultationTask

The owl:Class jolux:ConsultationTask is used for the different tasks of a jolux:Consultation.

jolux:hasSubTask

The object property jolux:hasSubTask is used to connect a jolux:Consultation to a jolux:ConsultationTask.

The following figure shows the general structure of a consultation:

_images/consultation.png

General structure of a consultation.#

There are four types of jolux:ConsultationTask:

  • jolux:ConsultationPreparation

  • jolux:ConsultationPhase

  • jolux:PositionStatementPublication

  • jolux:ResultOfAConsultationPublication

jolux:ConsultationPreparation

The owl:Class jolux:ConsultationPreparation is used for the preparation of a consultation. It contains mainly some metadata. It is not always present for every consultation.

jolux:ConsultationPhase

The owl:Class jolux:ConsultationPhase is used to form the actual object of the consultation.

The following figure shows the structure of the jolux:ConsultationPhase:

_images/consultation_phase.png

Structure of a jolux:ConsultationPhase. There are multiple documents of type jolux:DraftRelatedDocument.#

The most important properties for a jolux:ConsultationPhase are:

  • jolux:opinionIsAboutDraftDocument

  • jolux:opinionHasDraftRelatedDocument

jolux:opinionIsAboutDraftDocument

The property jolux:opinionIsAboutDraftDocument is used to connect the actual consultation document to the jolux:ConsultationPhase.

jolux:opinionHasDraftRelatedDocument

The property jolux:opinionHasDraftRelatedDocument is used to connect the accompanying documents to the different jolux:ConsultationTask (e.g. jolux:ConsultationPhase).

All the jolux:DraftRelatedDocument from the jolux:ConsultationPhase have a jolux:draftProcessDocumentType that has the supercategory https://fedlex.data.admin.ch/vocabulary/draft-document-type/10

The most important documents of the jolux:ConsultationPhase have the following entries from the draft document types vocabulary:

jolux:PositionStatementPublication

The owl:Class jolux:PositionStatementPublication is used to publish the complete collected position statements of the consultation recipients.

All the jolux:DraftRelatedDocument from the jolux:PositionStatementPublication have a jolux:draftProcessDocumentType that has the supercategory https://fedlex.data.admin.ch/vocabulary/draft-document-type/20

The most important document of the jolux:PositionStatementPublication has the following entry from the draft document types vocabulary:

jolux:ResultOfAConsultationPublication

The owl:Class jolux:ResultOfAConsultationPublication is used to publish the result of a consultation in form of a report of the consultation publishing authority.

All the jolux:DraftRelatedDocument from the jolux:ResultOfAConsultationPublication have a jolux:draftProcessDocumentType that has the supercategory https://fedlex.data.admin.ch/vocabulary/draft-document-type/30

The most important document of the jolux:ResultOfAConsultationPublication has the following entry from the draft document types vocabulary:

Datatype Properties#

jolux:Consultation#

The following SPARQL query shows all different datatype properties for jolux:Consultation. These properties are self explanatory.

jolux:ConsultationTask#

Object Properties#

jolux:Consultation#

Object properties that point to a vocabulary entry:

Object properties that point to an individual:

jolux:ConsultationTask#

Object properties that point to a vocabulary entry:

Object properties that point to an individual:

SPARQL Examples#

The following SPARQL query shows all the jolux:Consultation with their title in French that have a foreseen impact to the federal constitution:

PREFIX jolux: <http://data.legilux.public.lu/resource/ontology/jolux#>
SELECT * WHERE {

    ?consultation a jolux:Consultation;
        jolux:foreseenImpactToLegalResource <https://fedlex.data.admin.ch/eli/cc/1999/404>;
        jolux:eventTitle ?title.
  
    FILTER(lang(?title) = "fr")
}

The following SPARQL query shows all the planned consultations and the one that are in preparation with their title in German:

PREFIX jolux: <http://data.legilux.public.lu/resource/ontology/jolux#>
SELECT * WHERE {

	?consultation a jolux:Consultation;
        jolux:eventTitle ?title;
        jolux:consultationStatus ?status.
  
  VALUES ?status {
    <https://fedlex.data.admin.ch/vocabulary/consultation-status/0>
    <https://fedlex.data.admin.ch/vocabulary/consultation-status/1>
  }
   
  FILTER(lang(?title) = "de")
  }

The following SPARQL query gives the links to the Italian result reports of the 10 last closed consultations.

PREFIX jolux: <http://data.legilux.public.lu/resource/ontology/jolux#>
SELECT ?title ?date ?url WHERE {

	?consultation a jolux:Consultation;
        jolux:eventTitle ?title;
        jolux:hasSubTask ?result_phase, ?consultation_phase.
  
    FILTER(lang(?title) = "it")

    ?result_phase a jolux:ResultOfAConsultationPublication;
        jolux:opinionHasDraftRelatedDocument ?result.
    ?result jolux:draftProcessDocumentType <https://fedlex.data.admin.ch/vocabulary/draft-document-type/31>;
        jolux:isRealizedBy ?expression.
    ?expression jolux:language <http://publications.europa.eu/resource/authority/language/ITA>;
        jolux:isEmbodiedBy ?manifestation.
    ?manifestation jolux:userFormat <https://fedlex.data.admin.ch/vocabulary/user-format/pdf-a>;
        jolux:isExemplifiedBy ?url.
    
    ?consultation_phase a jolux:ConsultationPhase;
          jolux:eventEndDate ?date.

} ORDER BY DESC(?date)
LIMIT 10
Contents